本篇教程来自MC百科(mcmod.cn) 使用 CC BY-NC-ND协议。

处理支持:

奥术工作台坩埚注魔、给物品添加要素、给研究或物品等添加扭曲值、修改藏宝袋的奖励


首先是奥术工作台部分:
添加有序配方:
栗子:

mods.thaumcraft.Arcane.addShaped("ASPECTS", <minecraft:stonebrick:3> * 4, "ordo 1", 

[[<minecraft:stonebrick>, <minecraft:stonebrick>, null], 

[<minecraft:stonebrick>, <minecraft:stonebrick>, null], 

[null, null, null]]);


变量1为绑定的研究,必须研究了被绑定的研究才能使用该配方,可以绑定默认就激活的研究来使该配方默认激活(如栗子里的ASPECTS),变量2为输出的物品,变量3为输入的魔力,变量4到6为第一行输入物品,下面的同上.
这里顺便列出每种魔力的名字好了:
aer:风
ignis:火
aqua:水
terra:地
ordo:秩序
perditio:混沌

接下来是添加无序配方惹:
栗子:

mods.thaumcraft.Arcane.addShapeless("VOIDMETAL", <minecraft:ghast_tear>,

 "aqua 6, terra 6, perditio 6, ordo 6, aer 6, ignis 6", 

[<minecraft:ender_pearl>, <Thaumcraft:ItemResource:17>]);


嘛,除了addShaped变成了addShapeless就没什么变化了呢.

删除配方:
栗子:

mods.thaumcraft.Arcane.removeRecipe(<Thaumcraft:ItemArcaneDoor>);


只需填物品名称即可,他会删除该物品在奥术合成台里所有的配方(除去同一文件内添加在这条条目之后的配方),所以呢,如果你想要删除一个物品的合成配方再添加一个的话,记得写在同一个脚本里,并且写在这条的后面.

要素相关:
物品要素部分:
添加要素:
栗子:

mods.thaumcraft.Aspects.add(<minecraft:saddle>, "motus 4");


变量1为指定物品,变量2为指定单位的指定要素

这条就是给指定物品添加指定数量的指定要素
也就是说,扫描或分解这件物品的话,会在原有的要素上,添加指定要素

设置要素:
栗子:

mods.thaumcraft.Aspects.set(<Thaumcraft:ItemBucketPure>, "aqua 4, metallum 8, vacous 1, sano 2, auram 2");


变量1为指定物品,变量2为指定单位的指定要素

这条是将指定物品的所含要素修改为指定数量的指定要素
与上条不同之处在于这条是修改,而上一条是添加.


移除要素:
栗子:

mods.thaumcraft.Aspects.remove(<minecraft:glowstone_dust>, "lux 2");


变量1为指定物品,变量2为指定单位的指定要素

这条是在指定物品的所含要素内移除指定数量的指定要素

实体要素部分:
与物品要素基本没有什么不同,只是指定的目标不同.
添加要素:

mods.thaumcraft.Aspects.addEntity("Skeleton", "lucrum 2, mortuus 1");


变量1为指定实体,变量2为指定单位的指定要素设置要素


设置要素:

mods.thaumcraft.Aspects.setEntity("Arrow", "telum 1");


变量1为指定实体,变量2为指定单位的指定要素设置要素


移除要素:

mods.thaumcraft.Aspects.removeEntity("Creeper", "ignis 2");


变量1为指定实体,变量2为指定单位的指定要素设置要素


坩埚部分:
与奥术合成台部分无太大差别.

添加配方:

mods.thaumcraft.Crucible.addRecipe("ENTROPICPROCESSING", <minecraft:dirt>, <minecraft:sapling>, "terra 2, perditio 4");


变量1是绑定的研究,变量2是输出的物品,变量3是输入的物品,变量4是需要的源质.

移除配方:

mods.thaumcraft.Crucible.removeRecipe(<Thaumcraft:ItemResource:2>);


变量1是指定物品

用法与奥术合成台一样.

注魔部分:
注魔添加配方:

mods.thaumcraft.Infusion.addRecipe("NITOR", <Thaumcraft:ItemResource:1>, 

[<minecraft:fire_charge>, <Thaumcraft:ItemResource>, <minecraft:flint_and_steel>], 

"ignis 20, potentia 10, permutatio 12", <minecraft:fire> * 4, 5);


变量1是绑定的研究,变量2是核心物品(即为放在中心的物品),变量3到5都是输入的物品,变量6是输入的源质,变量7是输出的物品,变量8是注魔风险度(不知道具体是怎么计算的).


移除配方:

mods.thaumcraft.Infusion.removeRecipe(<Thaumcraft:ItemAmuletVis:1>);


变量1为指定物品

添加注魔法附魔配方:

mods.thaumcraft.Infusion.addEnchantment("XPBOOST", 45, 5, "victus 10, cognitio 8, vitreus 6",  

[<minecraft:experience_bottle>, <minecraft:experience_bottle>, <minecraft:experience_bottle>, <Thaumcraft:ItemResource:14>]);


变量1是绑定的配方,变量2是附魔ID,变量3是等级上限,变量4是输入的源质,变量5到8都是输入的物品.


移除注魔法附魔配方:

mods.thaumcraft.Infusion.removeEnchant(1);


变量1是附魔ID


藏宝袋部分:
添加物品:

mods.thaumcraft.Loot.addCommonLoot(<Thaumcraft:ItemNugget:16>, 40);

mods.thaumcraft.Loot.addUncommonLoot(<Thaumcraft:ItemNugget:31>, 20);

mods.thaumcraft.Loot.addRareLoot(<Thaumcraft:ItemEldritchObject:3>, 5);


变量1是指定物品,变量2是几率.

移除物品:

mods.thaumcraft.Loot.removeCommonLoot(<Thaumcraft:ItemBaubleBlanks>);

mods.thaumcraft.Loot.removeUncommonLoot(<Thaumcraft:ItemRingRunic>);

mods.thaumcraft.Loot.removeRareLoot(<minecraft:golden_apple:1>);


变量1是指定物品

扭曲部分:
添加的扭曲都是永久扭曲
研究添加扭曲:

mods.thaumcraft.Warp.addToResearch("BATHSALTS", 5);


变量1是指定研究,变量2是扭曲数值.

物品添加扭曲:

mods.thaumcraft.Warp.addToItem(<Thaumcraft:ItemBathSalts>, 5);


变量1是指定物品,变量2是扭曲数值.

移除研究的扭曲:

mods.thaumcraft.Warp.removeFromResearch("BOTTLETAINT");


变量1是指定研究.

移除物品的扭曲:

mods.thaumcraft.Warp.removeFromItem(<Thaumcraft:ItemBottleTaint>);


变量1是指定物品

全部扭曲去除:

mods.thaumcraft.Warp.removeAll();


全部研究扭曲去除:

mods.thaumcraft.Warp.removeAllResearch();


全部物品扭曲去除:

mods.thaumcraft.Warp.removeAllItems();



指令支持:

/minetweaker aspectList - 输出所有的要素


/minetweaker entities - 输出所有的实体


/minetweaker research [CATEGORY] - 输出指定类型所有的研究




注:所有栗子全部来自官方维基