本篇教程来自MC百科(mcmod.cn) 使用 CC BY-NC-SA 协议。

Railcraft（铁路增强）-MT魔改说明

Railcraft作为一个老牌mod，ModTweaker同样对其有相应的支持，不过有一些特殊的注意事项还是有必要在这里提出。

ModTweaker为如下的机器增加了配方支持：

Blast Furnace（高炉）
Coke Oven（焦炉）
Rock Crusher（碎石机）
Rolling Machine（辊压机）

1. Blast Furnace（高炉）

添加配方：

mods.railcraft.BlastFurnace.addRecipe(输入物品, 是否匹配MetaData, 是否匹配NBT数据, 所需时间, 输出物品);

移除配方：

mods.railcraft.BlastFurnace.removeRecipe(输出物品);

添加高炉燃料： （注意：需要该燃料本身为熔炉燃料才能添加到高炉燃料！）

mods.railcraft.BlastFurnace.addFuel(物品标记);

移除高炉燃料：

mods.railcraft.BlastFurnace.removeFuel(物品标记);

注意：输入物品与输出物品不支持矿物辞典！

来自ModTweaker官方Wiki的一个添加配方的例句：

mods.railcraft.BlastFurnace.addRecipe(<Railcraft:lantern.metal>, false, false, 130, <Railcraft:lantern.metal:5>);

效果是可以将 1 个铁灯在高炉中以 130 ticks 制成 1 个钢灯（如图所示）。

但是实际应用中，我们发现其他的金属灯甚至钢灯本身也能被烧制成钢灯（如图所示）。

这是为什么呢？

2. 有关matchDamage（匹配MetaData）与matchNBT（匹配NBT数据）

在ModTweaker为RC的部分支持中，包含了matchDamage与matchNBT的相关项目，而这一部分坑了无数的整合包作者，因此我们有必要进行讲解。

matchDamage指匹配MetaData，MetaData直观地说即为物品ID后的子ID，如橙色羊毛的ID为35:1，其中35为羊毛的物品ID，1即为MetaData。

matchNBT指匹配NBT数据，有关NBT数据的内容请移步MinecraftWiki 相关页面。

如果为true，则开启匹配；如果为false，则不进行匹配。

这一功能主要是为了匹配有耐久磨损或者有附魔的工具或武器，如下面的例子：

mods.railcraft.BlastFurnace.addRecipe(<minecraft:diamond_axe>, false, false, 20, <minecraft:diamond> * 2);

这里的matchDamage与matchNBT都为false，效果是可以将 1 个钻石斧（任意耐久任意附魔）在高炉中以 20 ticks 制成 2 个钻石（如图所示，左侧为NEI显示，右侧为实际应用）。

但是部分物品，其物品ID相同而MetaData不同，如果使用false则会出现如下例中出现的情况。

mods.railcraft.BlastFurnace.addRecipe(<ThermalFoundation:Ore>, false, false, 20, <ThermalFoundation:material:64>);

mods.railcraft.BlastFurnace.addRecipe(<ThermalFoundation:Ore:1>, false, false, 20, <ThermalFoundation:material:65>);

理想效果是可以将 1 个铜矿在高炉中以 20 ticks 制成 1 个铜锭，将 1 个锡矿在高炉中以 20 ticks 制成 1 个锡锭（一个用高炉烧矿的例子）。而NEI显示也是如此（如图所示）。

而当我们把锡矿放进高炉时，我们却意外地发现

这就是没有将matchDamage改为true的后果，如果出现类似的问题，请将matchDamage改为true。也希望这个问题不会再困扰到正在学习ModTweaker的你。

3. Coke Oven（焦炉）

添加配方：

mods.railcraft.CokeOven.addRecipe(输出物品, 输出液体, 输入物品, 所需时间);

移除配方：

mods.railcraft.CokeOven.removeRecipe(输出物品);

注意：输入物品与输出物品不支持矿物辞典！

来自ModTweaker官方Wiki的一个添加配方的例句：

mods.railcraft.CokeOven.addRecipe(<Railcraft:post>, <liquid:creosote> * 100, <minecraft:fence>, 400);

效果是可以将 1 个栅栏在焦炉中以 400 ticks 制成 1 个木桩，同时输出 100 mB 的杂酚油（如图所示）。

4. Rock Crusher（碎石机）

添加配方：

mods.railcraft.RockCrusher.addRecipe(输入物品, 是否匹配MetaData, 是否匹配NBT数据, 输出物品组, 几率数组);

移除配方：

mods.railcraft.RockCrusher.removeRecipe(输入物品);

注意：输入物品与输出物品不支持矿物辞典！

来自ModTweaker官方Wiki的一个添加配方的例句：

mods.railcraft.RockCrusher.addRecipe(<minecraft:piston>, false, false, [<minecraft:cobblestone> * 3, <minecraft:planks> * 2, <minecraft:redstone>, <minecraft:iron_ingot>], [0.9, 0.8, 0.4, 0.4]);

效果是可以将 1 个圆石在碎石机中以90%概率输出 3 个圆石，80%概率输出 2 个木板，40%概率输出 1 个红石，40%概率输出 1 个铁锭（如图所示）。

5. Rolling Machine（辊压机）

添加有序/无序配方：

mods.railcraft.Rolling.addShaped(输出物品, 输入物品组);

mods.railcraft.Rolling.addShapeless(输出物品, 输入物品组);

移除配方：

mods.railcraft.Rolling.removeRecipe(输出物品);

注意：输入物品与输出物品支持矿物辞典！

来自ModTweaker官方Wiki的一个添加有序配方的例句：

mods.railcraft.Rolling.addShaped(<minecraft:light_weighted_pressure_plate>, [[<minecraft:gold_nugget>, <minecraft:gold_nugget>, null], [<minecraft:gold_nugget>, <minecraft:gold_nugget>, null], [null, null, null]]);

效果是可以将 4 个金粒按照如图所示的摆法制作出 1 个测重压力板（轻质）。

来自ModTweaker官方Wiki的一个添加无序配方的例句：

mods.railcraft.Rolling.addShapeless(<Railcraft:routing.ticket.gold> * 2, [<minecraft:paper>, <minecraft:gold_nugget>]);

效果是可以将 1 个纸与 1 个金粒按照任意摆法制作出 2 个黄金车票（如图所示）。

铁路-MoT改教程

Railcraft（铁路增强）-MT魔改说明