IE作为一个可以说面面俱到的mod,自行为MineTweaker提供了MT配方,免去了另装ModTweaker的麻烦.

其为MT提供了以下机械的配方:

电弧炉(Arc Furnace)

高炉(Blast Furnace)

罐装机(Bottling Machine)

焦炉(Coke Oven)

粉碎机(Crusher)

斗轮挖掘机及矿脉(Excavator)

发酵机(Fermenter)

金属压印机(Metal Press)

炼油厂(Refinery)

压榨机(Squeezer)

标记为红色可省略

添加一个电弧炉配方

mods.immersiveengineering.ArcFurnace.addRecipe(<minecraft:gravel>, <minecraft:dirt> * 9, <ImmersiveEngineering:material:13>, 4600, 3600, [<ImmersiveEngineering:fluidContainers:4>], "Purifying");

参数从左到右为:

输出物品

输入物品(电弧炉左方格可放的物品)

副产物输出(矿渣栏出现的物品)

消耗时间(单位为tick,数值为正整数)

每tick消耗的能量(单位为RF)

添加剂(电弧炉右方格可放的物品)
配方类型(NEI查看合成时的类型,可自定义也可以使用IE自带的三种)

删除一个电弧炉配方
mods.immersiveengineering.ArcFurnace.removeRecipe(<ImmersiveEngineering:metal:7>);
参数为输出物品

添加一个高炉配方
mods.immersiveengineering.BlastFurnace.addRecipe(<ImmersiveEngineering:material:12>,<ImmersiveEngineering:material:11>, 4800,<ImmersiveEngineering:material:13>);

参数从左到右为:

输出物品

输入物品

消耗时间(单位为tick,数值为正整数)

副产物输出

删除一个高炉配方
mods.immersiveengineering.BlastFurnace.removeRecipe(<ImmersiveEngineering:metal:7>);
参数为:输出物品

添加一个高炉燃料

mods.immersiveengineering.BlastFurnace.addFuel(<ImmersiveEngineering:metal:17>,1200);
参数从左到右为:

作为燃料的物品

燃烧时间(单位为tick,数值为正整数)

删除一个高炉燃料
mods.immersiveengineering.BlastFurnace.removeFuel(<ImmersiveEngineering:material:6>);
参数为:需要删除作为燃料的物品

添加一个罐装机配方
mods.immersiveengineering.BottlingMachine.addRecipe(<minecraft:packed_ice>, <minecraft:ice>, <liquid:water> * 1000);
参数从左到右为:

输出物品

输入物品

输入流体

删除一个罐装机配方
mods.immersiveengineering.BottlingMachine.removeRecipe(<minecraft:water_bucket>);
参数为:输出物品

添加一个焦炉配方
mods.immersiveengineering.CokeOven.addRecipe(<minecraft:coal:1> * 2, 500, <minecraft:chest>, 1800);
参数从左到右为:

输出物品

输出杂酚油(单位为mB)

输入物品

消耗时间(单位为tick,数值为正整数)

删除一个焦炉配方
mods.immersiveengineering.CokeOven.removeRecipe(<ImmersiveEngineering:material:6>);
参数为:输出物品

添加一个粉碎机配方
mods.immersiveengineering.Crusher.addRecipe(<ImmersiveEngineering:metal> * 8, <ImmersiveEngineering:storage:8>, 8000, <minecraft:iron_ingot>, 0.5);

参数从左到右为:

输出物品1

输入物品

所需能量
输出物品2

输出物品2几率

删除一个粉碎机配方
mods.immersiveengineering.Crusher.removeRecipe(<minecraft:blaze_powder>);
参数为:输出物

斗轮挖掘机配方

mods.immersiveengineering.Excavator.addMineral("Sediment", 30, 15, ["sand", "sandstone"], [50, 15], [0, 1], false);

参数从左到右为:

矿脉

矿物比重

失败几率

矿脉产物

矿脉产出几率

维度ID

启用或禁用(true=启用,false=禁用,禁用的矿脉无法挖到矿物,忽略为启用)

删除一个矿脉

mods.immersiveengineering.Excavator.removeMineral("Bauxite");

参数为:矿脉名称

往矿脉里添加一种矿石

mods.immersiveengineering.Excavator.getMineral("Magnetite").addOre("oreNickel", 0.75);

参数从左到右为:

矿脉名称

矿石名称(可使用矿典)

矿石比重

往矿脉里移除一种矿石

mods.immersiveengineering.Excavator.getMineral("Magnetite").removeOre("oreGold");

参数从左到右为:

矿脉名称

矿石名称

添加一个发酵机配方

mods.immersiveengineering.Fermenter.addRecipe(<minecraft:blaze_powder>, <liquid:lava> * 80, <minecraft:nether_wart>, 80);

参数从左到右为:

输出物品

输出流体

输入物品

发酵时间

删除一个发酵机配方

mods.immersiveengineering.Fermenter.removeItemRecipe(<minecraft:blaze_powder>);

参数从左到右为:

输出物品

mods.immersiveengineering.Fermenter.removeFluidRecipe(<liquid:ethanol>);

参数从左到右为:

输出流体

添加一个金属压印机配方

mods.immersiveengineering.MetalPress.addRecipe(<minecraft:stone_slab> * 2, <minecraft:stone>, <ImmersiveEngineering:mold>, 500, 50);

参数从左到右为:

输出物品

输入物品

压印模具

所需能量

输入物品数量(也可以在输入物品处设置数量,如:<minecraft:stone>*50,但两种数量同时存在时取输入物品数量的值)

删除一个金属压印机配方

mods.immersiveengineering.MetalPress.removeRecipe(<ImmersiveEngineering:metal:30>);

参数为:输出物品

删除一个模具及其关联配方

mods.immersiveengineering.MetalPress.removeRecipeByMold(<ImmersiveEngineering:mold:2>);

参数为:模具

添加一个炼油厂配方

mods.immersiveengineering.Refinery.addRecipe(<liquid:lava> * 16, <liquid:plantoil> * 8, <liquid:biodiesel> * 8);

参数从左到右为:

输出流体

输入流体1

输入流体2

删除一个炼油厂配方

mods.immersiveengineering.Refinery.removeRecipe(<liquid:biodiesel>);

参数为:输出流体

添加一个压榨机配方

mods.immersiveengineering.Squeezer.addRecipe(<minecraft:melon_seeds> * 4, <liquid:water> * 500, <minecraft:melon_block>, 240);

参数从左到右为:

输出物品

输出流体

输入物品

所需时间(单位为tick)

删除一个压榨机配方

mods.immersiveengineering.Squeezer.removeItemRecipe(<minecraft:melon_seeds>);

参数为:输出物品

mods.immersiveengineering.Squeezer.removeFluidRecipe(<liquid:plantoil>);

参数为:输出流体