此处资料对应GTTweaker1.7.1。

GregTech5支持更改的机械设备：

·Alloy Smelter(合金炉)

·Amplifabricator(UU增幅液生产器)

·Arc Furnace(电弧炉)

·Assembler(组装机)

·Assembly Line(装配线) 

·Autoclave(高压釜)

·Blast Furnace(高炉)

·Brewery(酿造室)

·Canner(装罐机)

·Centrifuge(离心机)

·Chemical Bath(化学浸洗器)

·Chemical Reactor(化学反应釜)

·Circuit Assembler(电路组装机)

·Compressor(压缩机)

·Cutting Saw(板材切割机)

·Distillation Tower(蒸馏塔)

·Distillery(蒸馏室)

·Electrolyzer(电解器)

·Extractor(提取机)

·Extruder(压模器)

·Fermenter(发酵槽)

·Fluid Canner(流体灌装机)

·Fluid Extractor(流体提取机)

·Fluid Heater(流体加热器)

·Fluid Solidifier(流体固化器)

·Forge Hammer(锻造锤)

·Forming Press(冲压机床)

·Fuels(燃料)

·Fusion Reactor(核聚变反应堆)

·Implosion Compressor(聚爆压缩机)

·Lathe(车床)

·Mixer(搅拌机)

·Oil Cracker(石油裂化机)

·Ore Washer(洗矿厂)

·Packer(打包机)

·Plasma Arc Furnace(等离子电弧炉)

·Plate Bender(卷板机)

·Polarizer(两级磁化机)

·Precision Laser(精密激光蚀刻机)

·Printer(打印机)

·Pulverizer(磨粉机)

·Pyroluse Oven(热解炉)

·Separator(磁选矿厂)

·Sifter(宝石筛滤机)

·Slicer(切片机)

·Unpacker(解包机)

·Thermal Centrifuge(热力离心机) 

·VacuumFreezer(真空冷冻机)

·Wiremill(线材轧机)

#标记为红色的参数是可选的,可以忽略。没标的就老老实实写null

注：所需时间×消耗功率才是使用的总电量

添加‘合金炉’合成配方：

//输出物品, 输入物品1, 输入物品2, 所需时间(单位tick，下同), 消耗功率

例子：mods.gregtech.AlloySmelter.addRecipe(<minecraft:slime_ball>, <IC2:itemRubber>, <gregtech:gt.metaitem.01:32307> * 0, 800, 30);

注释：输入2(<gregtech:gt.metaitem.01:32307> * 0在此指‘模具’，其后面跟着 * 0指消耗数量‘0’即不会进行消耗。

添加‘UU增幅液生产器’合成配方：

//输入物品, 所需时间,输出UU(单位mb)

例子：mods.gregtech.Amplifabricator.addRecipe(<minecraft:tnt>, 200, 10);

添加‘电弧炉’合成配方：

//输出物品多个 （≤4）,输入物品, 输入流体, 输出概率, 所需时间,消耗功率

例子：mods.gregtech.ArcFurnace.addRecipe([<gregtech:gt.metaitem.01:11304> * 5, <gregtech:gt.metaitem.01:11304> * 4], <IC2:itemRecipePart:11>, <liquid:oxygen> * 504, [10000, 5000], 1200, 32);

注释：[10000, 5000]分别表示输出物品[<gregtech:gt.metaitem.01:11304> * 5, <gregtech:gt.metaitem.01:11304> * 4]的概率,具体为 数/10000,所以10000即是100%，5000即是50%。注意，概率的数值要与输出物品一一对应。

添加‘装配机’合成配方：

//①：输出物品, 输入物品1, 输入物品2, 输入流体, 所需时间, 消耗功率

例子：mods.gregtech.Assembler.addRecipe(<IC2:itemRTGPellet>, <gregtech:gt.metaitem.01:22032> * 6, <IC2:itemPlutonium> * 3, <liquid:glue> * 1000, 1200, 128);

//②：输出物品, 输入物品多个（≤6）, 输入流体, 所需时间, 消耗功率

例子：mods.gregtech.Assembler.addRecipe(<IC2:itemwcarbonrotor:1>, [<IC2:itemRecipePart:9> * 4, <gregtech:gt.metaitem.02:22084> * 2,<gregtech:gt.metaitem.01:27084> * 2],<liquid:molten.solderingalloy> * 288, 600, 480);

添加‘装配线’合成配方：

//前置扫描物品, 扫描所需时间, 输入物品多个（按顺序,≤16）,输入流体多个（按顺序,≤4）, 输出物品, 所需时间, 消耗功率

例子：AssemblyLine.addRecipe(<gregtech:gt.metaitem.01:32758>, 144000,[<gregtech:gt.metaitem.01:32758> * 4, <gregtech:gt.metaitem.03:32095> * 2, <gregtech:gt.metaitem.03:32094> * 32, <gregtech:gt.metaitem.03:32094> * 32, <gregtech:gt.blockmachines:2022> * 8, <gregtech:gt.blockmachines:884>, <gregtech:gt.metaitem.03:32052>*64,<gregtech:gt.metaitem.03:32052>*64, <gregtech:gt.metaitem.01:32677> * 8],  [<liquid:molten.neutronium> * 144, <liquid:lubricant> * 2880, <liquid:molten.solderingalloy> * 2880],<gregtech:gt.metaitem.01:32759>, 600, 512000);

添加‘高压釜’合成配方：

//输出物品, 输入物品, 输入流体, 输出概率, 消耗功率, 是否需要低重力环境

例子：mods.gregtech.Autoclave.addRecipe(<minecraft:diamond>, <gregtech:gt.metaitem.01:2500>, <liquid:water> * 200, 9000, 2000, 32, false);

添加‘高炉’合成配方:

//①：输出物品多个, 输入流体, 输入物品多个, 所需时间, 消耗功率, 所需炉温

例子：mods.gregtech.BlastFurnace.addRecipe([<gregtech:gt.blockmetal6:13>, <gregtech:gt.metaitem.01:2816>], <liquid:oxygen> * 9000, [<gregtech:gt.blockmetal8:2>], 1500, 120, 1500);

//②：输出物品多个, 输出流体, 输入物品多个, 输入流体, 所需时间, 消耗功率, 所需炉温

例子：mods.gregtech.BlastFurnace.addRecipe([<gregtech:gt.metaitem.01:12370>], <liquid:carbondioxide>*3000, [<gregtech:gt.metaitem.01:1010>,<gregtech:gt.metaitem.01:11081>],<liquid:nitrogen>*3000, 4950, 480, 3300);

添加‘酿造室’合成配方:

//输入流体, 输入物品, 输出流体, 是否为隐藏配方（即NEI查不到）

例子：mods.gregtech.Brewery.addRecipe(<liquid:ic2distilledwater> * 10000, <minecraft:nether_star>, <liquid:holywater> * 1000, false);

添加‘装罐机’合成配方:

//①：输出物品多个（≤2）, 输入物品1, 输入物品2, 所需时间, 消耗功率

例子：mods.gregtech.Canner.addRecipe([<IC2:itemTinCanFilled> * 4, <minecraft:sugar>], <minecraft:reeds> * 4, <IC2:itemTinCan>, 50, 200);

//②：输出物品, 输入物品1, 输入物品2, 所需时间, 能量消耗

例子：mods.gregtech.Canner.addRecipe(<gregtech:gt.metaitem.01:30377>,<gregtech:gt.metaitem.01:2377>*2,<IC2:itemCellEmpty>,100,5);

添加‘离心机’合成配方:

//输出物品多个（≤6）, 输出流体, 输入物品1, 输入物品2, 输入流体, 输出概率, 所需时间, 消耗功率

例子：mods.gregtech.Centrifuge.addRecipe([<minecraft:sand> * 12, <minecraft:gunpowder> * 15, <minecraft:flint> * 6], <liquid:water> * 200, <IC2:blockITNT> * 4, <gregtech:gt.metatool.01:26>, <liquid:potion.mineralwater> * 200, [10000, 9000, 8000], 100, 50);

添加‘化学浸洗机’合成配方:

//输出物品多个（≤3）, 输入物品, 输入流体, 输出概率, 所需时间, 消耗功率

例子：mods.gregtech.ChemicalBath.addRecipe([<IC2:itemToolPainterBlack>], <IC2:itemToolPainter>, <liquid:dye.watermixed.dyeblack> * 144, [10000], 200, 2);

添加‘化学反应釜’合成配方:

//①：输出物品, 输出流体, 输入物品, 输入物品2, 输入流体, 所需时间, 消耗功率（不填即自动设为30）

例子：mods.gregtech.ChemicalReactor.addRecipe(<IC2:itemFertilizer> * 2, <liquid:potion.mineralwater>, <minecraft:dye:15>, <gregtech:gt.metaitem.01:2815>, <liquid:water>, 200);

//②：输出物品1, 输出物品2, 输出流体, 输入物品1, 输入物品2, 输入流体, 所需时间, 消耗功率

例子：mods.gregtech.ChemicalReactor.addRecipe(null,<gregtech:gt.metaitem.01:30648>,<liquid:saltwater>*1000,<gregtech:gt.metaitem.01:30682>*1,<gregtech:gt.metaitem.01:2685>*1,<liquid:hypochlorousacid>*1000,100,120);

添加‘电路组装机’合成配方：

//输出物品, 输入物品多个（≤6）, 输入流体, 所需时间, 消耗功率

例子：

mods.gregtech.CircuitAssembler.addRecipe(<customthings:item:13>, [<gregtech:gt.blockmachines:4115> * 1, <IC2:itemPartCircuitAdv> * 4, <gregtech:gt.metaitem.03:32014> * 4, <gregtech:gt.metaitem.01:32718> * 24, <gregtech:gt.metaitem.03:32039> * 16, <gregtech:gt.blockmachines:1380> * 12],<liquid:molten.solderingalloy> * 288, 1600, 30);

添加‘压缩机’合成配方：

//输出物品, 输入物品, 所需时间, 消耗功率

例子：（假装有例子）

添加‘板材切割机’合成配方:

//①：输出物品多个（≤2）, 输入物品, 输入流体, 所需时间, 消耗功率

例子：mods.gregtech.CuttingSaw.addRecipe([<minecraft:planks> * 3, <minecraft:wool> * 3], <minecraft:bed>, <liquid:water> * 12, 30, 30);

//②：输出物品1, 输出物品2, 输入物品, [集成电路配置或输入流体], 所需时间, 消耗功率

例子：（假装有例子）

添加‘蒸馏塔’合成配方:

//addUniversal可能是指为蒸馏室添加对应配方Recipe(输出流体多个(≤12), 输出物品, 输入流体, 所需时间, 消耗功率)

例子：mods.gregtech.DistillationTower.addRecipe([<liquid:lava> * 800, <liquid:liquid_heavy_oil> * 100, <liquid:liquid_medium_oil> * 75, <liquid:liquid_light_oil> * 25],  <gregtech:gt.metaitem.01:2940> * 4, <liquid:ic2pahoehoelava> * 1000, 50, 100);

添加‘蒸馏室’合成配方:

//输出流体, 输入集成电路, 输入流体, 所需时间, 消耗功率, 是否隐藏

例子：mods.gregtech.Distillery.addRecipe(<liquid:potion.chocolatemilk> * 250, <gregtech:gt.integrated_circuit:4> * 0, <liquid:milk> * 250, 80, 30, false);

添加‘电解槽’合成配方：

//输出物品多个, 输出流体, 输入物品, 输入单元, 输入流体, 输出概率, 所需时间, 消耗功率

例子：mods.gregtech.Electrolyzer.addRecipe([<gregtech:gt.metaitem.01:2086> * 3, <gregtech:gt.metaitem.01:1086> * 4, <gregtech:gt.metaitem.01:86> * 5], <liquid:molten.gold>,  <gregtech:gt.blockmetal5:12>, <gregtech:gt.neutronreflector>, <liquid:molten.platinum>, [10000, 8000, 6000], 1000, 40000);

添加‘提取机’合成配方：

//输出物品, 输入物品, 所需时间, 消耗功率

例子：

 mods.gregtech.Extractor.addRecipe(<gregtech:gt.metaitem.01:2896> * 2, <TConstruct:strangeFood>);

添加‘压模器’合成配方：

//输出物品, 输入物品, 输入模板, 所需时间, 消耗功率

例子：mods.gregtech.Extruder.addRecipe(<minecraft:quartz_block>, <minecraft:quartz> * 4, <gregtech:gt.metaitem.01:32363> * 0, 120, 128);

添加‘发酵槽’合成配方：

//输出流体, 输入流体, 所需时间, 是否为隐藏配方（即NEI查不到）

例子：mods.gregtech.Fermenter.addRecipe(<liquid:ic2pahoehoelava> * 50, <liquid:lava> * 1000, 20, false);

添加‘流体灌装机’合成配方：

//输出物品, 输入物品, 输出流体, 输入流体

例子：mods.gregtech.FluidCanner.addRecipe(<IC2:itemMugCoffee:1>, <IC2:itemMugEmpty>, <liquid:steam> * 200, <liquid:potion.darkcoffee> * 500);

添加‘流体提取机’合成配方：

//输出物品, 输入物品, 输出流体, 输出概率, 所需时间, 消耗功率

例子:mods.gregtech.FluidExtractor.addRecipe(<gregtech:gt.metaitem.01:30702>, <minecraft:packed_ice> , <liquid:ice> * 4000, 6000, 20, 2);

添加‘流体加热器’合成配方：

//输出流体, 输入电路, 输入流体, 所需时间, 消耗功率

例子：mods.gregtech.FluidHeater.addRecipe(<liquid:ic2hotcoolant> * 250, <gregtech:gt.integrated_circuit> * 0, <liquid:ic2coolant> * 250, 40, 20);

添加‘流体固化器’合成配方：

//输出物品, 输入模具, 输入流体, 所需时间, 消耗功率

例子：mods.gregtech.FluidSolidifier.addRecipe(<minecraft:packed_ice>, <gregtech:gt.metaitem.01:32308> * 0, <liquid:ice> * 4000, 480, 64);

添加‘锻造锤’合成配方：

//输出物品, 输入物品, 所需时间, 消耗功率

例子：mods.gregtech.ForgeHammer.addRecipe(<gregtech:gt.metaitem.02:22874>, <gregtech:gt.metaitem.01:23874> * 2, 20, 16);

添加‘冲压机床’合成配方：

//输出物品, 输入物品1, 输入物品2, 所需时间, 消耗功率

例子：mods.gregtech.FormingPress.addRecipe(<gregtech:gt.metaitem.01:32200> * 12, <IC2:blockAlloyGlass>, <gregtech:gt.metaitem.01:32316>, 200, 480);

添加‘燃料’合成配方：

//输出物品, 输入物品, 每mB输出 

//1000mB每个输入等于1000mB

例子I：mods.gregtech.Fuels.addDieselFuel(<IC2:itemCellEmpty>, <gregtech:gt.metaitem.01:30730>, 250);

例子II:mods.gregtech.Fuels.addGasTurbineFuel(<IC2:itemCellEmpty>, <IC2:itemCellEmpty:14>, 100);

例子III：mods.gregtech.Fuels.addThermalGeneratorFuel(<IC2:itemCellEmpty>, <IC2:itemCellEmpty:11>, 1000);

例子IV：mods.gregtech.Fuels.addDenseFluidFuel(<IC2:itemCellEmpty>, <gregtech:gt.metaitem.01:30964>, 2000);

例子V：mods.gregtech.Fuels.addPlasmaGeneratorFuel(<IC2:itemCellEmpty>, <IC2:itemCellEmpty:2>, 20);

例子VI：mods.gregtech.Fuels.addMagicGeneratorFuel(<gregtech:gt.metaitem.01:24532>, <minecraft:dragon_egg>, 20000)

添加‘核聚变’合成配方：

//输出流体, 1输入流体1, 2输入流体2, 所需时间, 消耗功率, 启动所需能量

例子:mods.gregtech.FusionReactor.addRecipe(<liquid:potion.diablosauce.strong> * 5, <liquid:molten.plutonium> * 100, <liquid:molten.naquadah> * 50, 200, 5000, 10000000); 

添加‘聚爆压缩机’合成配方：

//输出物品多个（≤2）, 输入物品, TNT数量

例子:mods.gregtech.ImplosionCompressor.addRecipe([<minecraft:bedrock>, <gregtech:gt.metaitem.01:2816> * 16], <gregtech:gt.metaitem.01:21327> * 32, 64);

添加‘车床’合成配方：

//输出物品多个（≤2）,输入物品,所需时间,消耗功率

例子:mods.gregtech.Lathe.addRecipe([<minecraft:redstone>, <minecraft:stick>], <minecraft:redstone_torch>, 640, 16);

添加‘搅拌机’合成配方：

//输出物品, 输出流体, 输入物品多个（≤4）, 输入流体, 所需时间, 消耗功率

例子:mods.gregtech.Mixer.addRecipe(<IC2:itemFertilizer>, <liquid:dye.watermixed.dyered> * 1000, [<minecraft:sand>, <minecraft:double_plant:4>], <liquid:water> * 1000, 100, 16);

添加‘石油裂化机’合成配方：

//①：输出流体, 输入流体, 所需时间, 消耗功率（此形式可能不再可用）

例子:（假装有例子）

//②：配置电路, 输出流体, 输入流体1, 输入流体2, 所需时间, 消耗功率

例子:（假装有例子）

添加‘洗矿厂’合成配方：

//输出物品1, 输出物品2, 输出物品3, 输入流体（不填即自动设为1000mB水）, 所需时间, 消耗功率

例子:（假装有例子）

添加‘打包机’合成配方：

//输出物品, 输入物品1, 输入物品2, 所需时间, 消耗功率

例子:mods.gregtech.Packer.addRecipe(<minecraft:iron_block>, <minecraft:iron_ingot> * 9, <gregtech:gt.metaitem.01:32497>, 50, 25);

添加‘等离子电弧炉’合成配方：

//输出物品多个（≤4）, 输出流体, 输入物品, 输入流体, 输出概率, 所需时间, 消耗功率

例子:mods.gregtech.PlasmaArcFurnace.addRecipe([<IC2:itemCellEmpty:13>], <liquid:nitrogen> * 250, <IC2:itemCellEmpty:14>, <liquid:plasma.nitrogen> * 250, [10000], 65, 30);

添加‘卷板机’合成配方：

//输出物品, 输入物品, 所需时间, 消耗功率

例子:mods.gregtech.PlateBender.addRecipe(<IC2:itemDensePlates:7>, <gregtech:gt.metaitem.01:17804> * 9, 3600, 96);

添加‘磁化机’合成配方：

//输出物品, 输入物品, 所需时间, 消耗功率

例子:mods.gregtech.Polarizer.addRecipe(<IC2:itemStaticBoots>, <minecraft:iron_boots>, 600, 30);

添加‘精密激光蚀刻机’合成配方：

//输出物品, 输入透镜, 输入物品, 所需时间, 消耗功率, 是否需要超净间

例子:mods.gregtech.PrecisionLaser.addRecipe(<gregtech:gt.metaitem.02:29500>, <gregtech:gt.metaitem.01:24500> * 0, <minecraft:diamond> * 4, 1200, 480);

添加‘土高炉’合成配方：

//输出物品1, 输出物品2, 输入物品1, 输入物品2, 所需时间, 耗煤数

例子:（假装有例子）

添加‘打印机’合成配方：

//输出物品, 输入物品, 输入物品（闪存）, 输入流体, 所需时间, 消耗功率

例子:mods.gregtech.Printer.addRecipe(<minecraft:writable_book>, <minecraft:book>, <minecraft:feather>, <liquid:squidink>, 25, 15);

添加‘磨粉机’合成配方：

//输出物品多个（≤4）, 输入物品, 输出概率, 所需时间, 消耗功率

例子:mods.gregtech.Pulverizer.addRecipe([<minecraft:dirt>, <IC2:itemFuelPlantBall>, <minecraft:red_mushroom>, <minecraft:brown_mushroom>], <minecraft:dirt:2>, [10000, 3000, 1500, 1500], 400, 2);

添加‘热解炉’合成配方：

//输出物品, 输出流体, 集成电路配置, 输入物品, 输入流体, 所需时间, 消耗功率

例子:mods.gregtech.PyrolyseOven.addRecipe(recipe needed);

mods.gregtech.PyrolyseOven.addRecipe(<minecraft:coal:1>*32,<liquid:creosote>*4000,1,<GalaxySpace:proximabburntlog>*16,null,640,64);

添加‘磁选矿厂’合成配方：

//输出物品多个（≤3）, 输入物品, 输出概率, 所需时间, 消耗功率

例子:mods.gregtech.Separator.addRecipe([<gregtech:gt.metaitem.02:27500>, <gregtech:gt.metaitem.01:1324> * 2, <gregtech:gt.metaitem.01:324> * 4], <gregtech:gt.metaitem.01:2506>, [5000, 2000, 1500], 200, 300);

添加‘宝石筛滤机’合成配方：

//输出物品多个（≤9）, 输入物品, 输出概率, 所需时间, 消耗功率

例子:mods.gregtech.Sifter.addRecipe([<minecraft:wheat_seeds>, <gregtech:gt.metaitem.01:2299>, <IC2:itemFertilizer>], <minecraft:dirt>, [2000, 500, 250], 10, 5);

添加‘切片机’合成配方：

//输出物品, 输入物品, 输入刀片, 所需时间, 消耗功率

例子:mods.gregtech.Slicer.addRecipe(<minecraft:melon> * 8, <minecraft:melon_block>, <gregtech:gt.metaitem.01:32398> * 0, 100, 8);

添加‘热力离心机’合成配方：

//输出物品1, 输出物品2, 输出物品3, 输入物品, 所需时间, 消耗功率

例子：（假装有例子）

添加‘解包机’合成配方：

//输出物品1, 输出物品2, 输入物品, 所需时间, 消耗功率

例子:mods.gregtech.Unpacker.addRecipe(<minecraft:sand> * 4, <minecraft:gunpowder> * 5, <minecraft:tnt>, 50, 200);

添加‘真空冷冻机’合成配方：

//输出物品, 输入物品, 所需时间（功率会自动设为120）

例子:mods.gregtech.VacuumFreezer.addRecipe(<IC2:itemCellEmpty:2>, <IC2:itemCellEmpty:11>, 50);

添加‘线材轧机’合成配方：

//输出物品, 输入物品, 所需时间, 消耗功率

例子:mods.gregtech.Wiremill.addRecipe(<minecraft:string> * 4, <minecraft:wool>, 100, 50);